[SOLVED] No sound from any application ?

[Ronald Sterijuanna]

I have Asus Xonar DGX soundcard and using windows 11 operating system. My selected audio source is correct and no problem when doing the sound tests from windows settings. The startup and other windows sounds also play without issue. However, I get no sounds from any applications, be it media player or browser. Furthermore, I have allowed the audio device to play application and windows sounds in settings. It was all correctly a hours ago. Problem probably started right after I run some batch file to uninstall edge completely. Is there any solution to this?

Specs:
i5-2400
8gb ddr3
gigabyte 1050ti
Asus Xonar DGX
Thermaltake litepower 550
500gb Apacer SSD + 2TB toshiba HD

 

[SkyNetRising]

Problem probably started right after I run some batch file to uninstall edge completely.

Can you show contents of this batch file?

 

[Ronald Sterijuanna]

Can you show contents of this batch file?

@echo off

:: Creator: Dave Kirkwood
:: Modified:By Britec
:: Created: 24/09/2020
:: Updated: 21/09/2022
::

:: First Stop Microsoft Edge Task
taskkill /F /IM msedge.exe  >nul 2>&1


CD %HOMEDRIVE%%HOMEPATH%\Desktop
echo %CD%


REM ************ Main process *****************

echo *** Removing Microsoft Edge ***
call :killdir C:\Windows\SystemApps\Microsoft.MicrosoftEdge_8wekyb3d8bbwe
call :killdir "C:\Program Files (x86)\Microsoft\Edge"
call :killdir "C:\Program Files (x86)\Microsoft\EdgeUpdate"
call :killdir "C:\Program Files (x86)\Microsoft\EdgeCore"
call :killdir "C:\Program Files (x86)\Microsoft\EdgeWebView"
echo *** Modifying registry ***
call :editreg
echo *** Removing shortcuts ***
call :delshortcut "C:\Users\Public\Desktop\Microsoft Edge.lnk"
call :delshortcut "%ProgramData%\Microsoft\Windows\Start Menu\Programs\Microsoft Edge.lnk"
call :delshortcut "%APPDATA%\Microsoft\Internet Explorer\Quick Launch\User Pinned\TaskBar\Microsoft Edge.lnk"
echo Finished!
pause
exit

REM ************ KillDir: Take ownership and remove a directory *****************

:killdir
echo|set /p=Removing dir %1
if exist %1 (
    takeown /a /r /d Y /f %1 > NUL
    icacls %1 /grant administrators:f /t > NUL
    rd /s /q %1 > NUL
    if exist %1 (
        echo ...Failed.
    ) else (
        echo ...Deleted.
    )
) else (
    echo ...does not exist.
)
exit /B 0

REM ************ Edit registry to add do not update Edge key *****************

:editreg
echo|set /p=Editting registry
echo Windows Registry Editor Version 5.00 > RemoveEdge.reg
echo. >> RemoveEdge.reg
echo [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\EdgeUpdate] >> RemoveEdge.reg
echo "DoNotUpdateToEdgeWithChromium"=dword:00000001 >> RemoveEdge.reg
echo. >> RemoveEdge.reg
echo [-HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Active Setup\Installed Components\{9459C573-B17A-45AE-9F64-1857B5D58CEE}] >> RemoveEdge.reg

regedit /s RemoveEdge.reg
del RemoveEdge.reg
echo ...done.
exit /B 0

:: Delete Microsoft Edge Folders
rmdir /s /q "C:\Program Files (x86)\Microsoft\Edge"
rmdir /s /q "C:\Program Files (x86)\Microsoft\EdgeCore"
rmdir /s /q "C:\Program Files (x86)\Microsoft\EdgeWebView"
rmdir /s /q "C:\Program Files (x86)\Microsoft\Temp"

:: Delete Edge Icons, from all users
for /f "delims=" %%a in ('dir /b "C:\Users"') do (
del /S /Q "C:\Users\%%a\Desktop\edge.lnk" >nul 2>&1
del /S /Q "C:\Users\%%a\Desktop\Microsoft Edge.lnk" >nul 2>&1)

:: Delete additional files
if exist "C:\Windows\System32\MicrosoftEdgeCP.exe" (
for /f "delims=" %%a in ('dir /b "C:\Windows\System32\MicrosoftEdge*"') do (
takeown /f "C:\Windows\System32\%%a" > NUL 2>&1
icacls "C:\Windows\System32\%%a" /inheritance:e /grant "%UserName%:(OI)(CI)F" /T /C > NUL 2>&1
del /S /Q "C:\Windows\System32\%%a" > NUL 2>&1))

:delshortcut
echo|set /p=Removing shortcut %1
if exist %1 (
    del %1
    echo ...done.
) else (
    echo ...does not exist.
)
exit /B 0

 

[Ronald Sterijuanna]

Fixed, somehow my apps were muted in audio mixer. Took a while to figure out as I am quite new to windows 11 after all. 😛 Also, literally none of the few articles I checked mentioned this solution, why 😾